mirror/pojokcodeid.nvim-lazy
1
0
Fork 0
mirror of https://github.com/pojokcodeid/nvim-lazy.git synced 2025-06-24 01:38:47 +02:00
Code Issues Projects Releases Packages Wiki Activity Actions

add: blade treesitter config

Browse source
This commit is contained in:
asep.komarudin 2024-06-25 10:25:26 +07:00
parent b9949062dc
commit fbc8a53840
19 changed files with 177 additions and 14 deletions
Download patch file Download diff file Expand all files Collapse all files

36
after/queries/html/injections.scm Normal file
View file

@ -0,0 +1,36 @@
;; extends
; AlpineJS attributes
(attribute
(attribute_name) @_attr
(#lua-match? @_attr "^x%-%l")
(#not-any-of? @_attr "x-teleport" "x-ref" "x-transition")
(quoted_attribute_value
(attribute_value) @injection.content)
(#set! injection.language "javascript"))
; Blade escaped JS attributes
; <x-foo ::bar="baz" />
(element
(_
(tag_name) @_tag
(#lua-match? @_tag "^x%-%l")
(attribute
(attribute_name) @_attr
(#lua-match? @_attr "^::%l")
(quoted_attribute_value
(attribute_value) @injection.content)
(#set! injection.language "javascript"))))
; Blade PHP attributes
; <x-foo :bar="$baz" />
(element
(_
(tag_name) @_tag
(#lua-match? @_tag "^x%-%l")
(attribute
(attribute_name) @_attr
(#lua-match? @_attr "^:%l")
(quoted_attribute_value
(attribute_value) @injection.content)
(#set! injection.language "php_only"))))