mirror of
https://github.com/nix-community/nixvim.git
synced 2025-06-25 10:18:36 +02:00
3f9effc575
* barbar: package option * Base16: package option * gruvbox: package option * nord: package option * one: package option * onedark: package option * tokyonight: package option * nvim-cmp: package option * coq: package option * lspkind: package option * helpers: added package option to mkPlugin * fugitive: package option * gitgutter: package option * gitsigns: package option * neogit: package option * ledger: package option * nix: package option * plantuml-syntax: package option * treesitter-context: package option + formatting * treesitter-refactor: package option + formatting * treesitter: package option * zig: package option * null-ls: package option * null-ls/servers: package option * lsp-lines: package option * lspsaga: package option * trouble: package option * luasnip: added description for package option * airline: package option * lightline: package option * lualine: package option * telescope: package option * telescope/frecency: package option * telescope/fzf-native: package option * telescope/media-files: package option * comment-nvim: package option * vim-commentary: package option * dashboard: package option * easyescape: package option * emmet: package option * endwise: package option * floaterm: package option * goyo: package option * intellitab: package option * mark-radar: package option * notify: package option * nvim-autopairs: package option * nvim-tree: package option * project-nvim: package option * specs: package option * startify: package option * surround: package option * undotree: package option
96 lines
2.6 KiB
Nix
96 lines
2.6 KiB
Nix
{ pkgs, config, lib, ... }:
|
|
with lib;
|
|
let
|
|
cfg = config.plugins.lightline;
|
|
helpers = import ../helpers.nix { inherit lib; };
|
|
in
|
|
{
|
|
options = {
|
|
plugins.lightline = {
|
|
enable = mkEnableOption "Enable lightline";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.vimPlugins.lightline-vim;
|
|
description = "Plugin to use for lightline";
|
|
};
|
|
|
|
colorscheme = mkOption {
|
|
type = with types; nullOr str;
|
|
default = config.colorscheme;
|
|
description = "The colorscheme to use for lightline. Defaults to .colorscheme.";
|
|
example = "gruvbox";
|
|
};
|
|
|
|
componentFunction = mkOption {
|
|
default = null;
|
|
type = with types; nullOr (attrsOf str);
|
|
description = ''
|
|
A list of function component definitions.
|
|
|
|
You should define the functions themselves in extraConfig
|
|
'';
|
|
example = ''
|
|
plugins.lightline = {
|
|
enable = true;
|
|
componentFunction = {
|
|
readonly = "LightlineReadonly";
|
|
};
|
|
|
|
extraConfig = '''
|
|
function! LightlineReadonly()
|
|
return &readonly && &filetype !=# 'help' ? 'RO' : '''
|
|
endfunction
|
|
''';
|
|
};
|
|
'';
|
|
};
|
|
|
|
component = mkOption {
|
|
default = null;
|
|
type = with types; nullOr (attrsOf str);
|
|
description = "Lightline component definitions. Uses 'statusline' syntax. Consult :h 'statusline' for a list of what's available.";
|
|
};
|
|
|
|
active = mkOption {
|
|
default = null;
|
|
type = types.nullOr (types.submodule {
|
|
options =
|
|
let
|
|
listType = with types; nullOr (listOf (listOf str));
|
|
in
|
|
{
|
|
left = mkOption {
|
|
type = listType;
|
|
description = "List of components that will show up on the left side of the bar";
|
|
default = null;
|
|
};
|
|
|
|
right = mkOption {
|
|
type = listType;
|
|
description = "List of components that will show up on the right side of the bar";
|
|
default = null;
|
|
};
|
|
};
|
|
});
|
|
};
|
|
|
|
modeMap = mkOption {
|
|
type = with types; nullOr (attrsOf str);
|
|
description = "Mode name mappings";
|
|
default = null;
|
|
};
|
|
};
|
|
};
|
|
|
|
config =
|
|
let
|
|
configAttrs = filterAttrs (_: v: v != null) {
|
|
inherit (cfg) colorscheme active component componentFunction modeMap;
|
|
};
|
|
in
|
|
mkIf cfg.enable {
|
|
extraPlugins = [ cfg.package ];
|
|
globals.lightline = mkIf (configAttrs != { }) configAttrs;
|
|
};
|
|
}
|