mirror of
https://github.com/nix-community/nixvim.git
synced 2025-06-21 00:25:42 +02:00
d2afb176ff
Let's simplify things by defining all modules in `./plugins`, `./modules` and `./wrappers/modules`. Instead of currying `pkgs` into a bootstrapping module, we can require `defaultPkgs` be provided as a special arg. This refactor allows us to completely remove `flake-modules/modules.nix`!
65 lines
1.5 KiB
Nix
65 lines
1.5 KiB
Nix
default_pkgs:
|
|
{ self, getHelpers }:
|
|
{
|
|
pkgs ? default_pkgs,
|
|
extraSpecialArgs ? { },
|
|
_nixvimTests ? false,
|
|
module,
|
|
}:
|
|
let
|
|
inherit (pkgs) lib;
|
|
|
|
helpers = getHelpers pkgs _nixvimTests;
|
|
shared = import ./_shared.nix helpers {
|
|
inherit pkgs lib;
|
|
config = { };
|
|
};
|
|
|
|
handleAssertions =
|
|
config:
|
|
let
|
|
failedAssertions = map (x: x.message) (lib.filter (x: !x.assertion) config.assertions);
|
|
in
|
|
if failedAssertions != [ ] then
|
|
throw "\nFailed assertions:\n${builtins.concatStringsSep "\n" (map (x: "- ${x}") failedAssertions)}"
|
|
else
|
|
lib.showWarnings config.warnings config;
|
|
|
|
mkNvim =
|
|
mod:
|
|
let
|
|
evaledModule = lib.evalModules {
|
|
modules = [
|
|
mod
|
|
{ wrapRc = true; }
|
|
] ++ shared.topLevelModules;
|
|
specialArgs = {
|
|
inherit helpers;
|
|
defaultPkgs = pkgs;
|
|
} // extraSpecialArgs;
|
|
};
|
|
config = handleAssertions evaledModule.config;
|
|
in
|
|
(pkgs.symlinkJoin {
|
|
name = "nixvim";
|
|
paths = [
|
|
config.finalPackage
|
|
config.printInitPackage
|
|
] ++ pkgs.lib.optional config.enableMan self.packages.${pkgs.stdenv.hostPlatform.system}.man-docs;
|
|
meta.mainProgram = "nvim";
|
|
})
|
|
// rec {
|
|
inherit config;
|
|
inherit (evaledModule) options;
|
|
extend =
|
|
extension:
|
|
mkNvim {
|
|
imports = [
|
|
mod
|
|
extension
|
|
];
|
|
};
|
|
nixvimExtend = lib.warn "<nixvim>.nixvimExtend has been renamed to <nixvim>.extend" extend;
|
|
};
|
|
in
|
|
mkNvim module
|