mirror of
https://github.com/nix-community/nixvim.git
synced 2025-06-21 00:25:42 +02:00
44849233e0
This commit adds support for byte compiling lua configuration files. It's enabled by default (if byte compiling is enabled at all) and can be disabled with `performance.byteCompileLua.configs` toggle. To implement this feature `extraFiles.<name>.finalSource` internal read-only option is introduced. `source` option cannot be used because it's user configurable. In order to access the values of the `performance.byteCompileLua` options, parent config is added to specialArgs of extraFiles submodule. Then the usages of `source` option changed to `finalSource` in all relevant places (filesPlugin and wrappers). Added more helpers for various cases of byte compiling: * `byteCompileLuaFile` byte compiles lua file * `byteCompileLuaHook` is a setup hook that byte compiles all lua files * `byteCompileLuaDrv` overrides derivation by adding byteCompileLuaHook to it Added tests to validate that extraFiles specified by various methods are handled correctly. Added a separate home-manager test, that is intended to validate that extraFiles propagated to wrapper modules are correctly byte compiled.
112 lines
3 KiB
Nix
112 lines
3 KiB
Nix
{
|
|
lib,
|
|
helpers,
|
|
pkgs,
|
|
config,
|
|
...
|
|
}:
|
|
let
|
|
fileTypeModule =
|
|
{
|
|
name,
|
|
config,
|
|
options,
|
|
topConfig,
|
|
...
|
|
}:
|
|
{
|
|
options = {
|
|
enable = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = true;
|
|
description = ''
|
|
Whether this file should be generated.
|
|
This option allows specific files to be disabled.
|
|
'';
|
|
};
|
|
|
|
target = lib.mkOption {
|
|
type = lib.types.str;
|
|
defaultText = lib.literalMD "the attribute name";
|
|
description = ''
|
|
Name of symlink, relative to nvim config.
|
|
'';
|
|
};
|
|
|
|
text = lib.mkOption {
|
|
type = with lib.types; nullOr lines;
|
|
default = null;
|
|
description = "Text of the file.";
|
|
};
|
|
|
|
source = lib.mkOption {
|
|
type = lib.types.path;
|
|
description = "Path of the source file.";
|
|
};
|
|
|
|
finalSource = lib.mkOption {
|
|
type = lib.types.path;
|
|
description = "Path to the final source file.";
|
|
readOnly = true;
|
|
visible = false;
|
|
internal = true;
|
|
};
|
|
};
|
|
|
|
config =
|
|
let
|
|
derivationName = "nvim-" + lib.replaceStrings [ "/" ] [ "-" ] name;
|
|
in
|
|
{
|
|
target = lib.mkDefault name;
|
|
source = lib.mkIf (config.text != null) (
|
|
# mkDerivedConfig uses the option's priority, and calls our function with the option's value.
|
|
# This means our `source` definition has the same priority as `text`.
|
|
lib.mkDerivedConfig options.text (pkgs.writeText derivationName)
|
|
);
|
|
finalSource =
|
|
# Byte compile lua files if performance.byteCompileLua option is enabled
|
|
if
|
|
lib.hasSuffix ".lua" config.target
|
|
&& topConfig.performance.byteCompileLua.enable
|
|
&& topConfig.performance.byteCompileLua.configs
|
|
then
|
|
if lib.isDerivation config.source then
|
|
# Source is a derivation
|
|
helpers.byteCompileLuaDrv config.source
|
|
else
|
|
# Source is a path or string
|
|
helpers.byteCompileLuaFile derivationName config.source
|
|
else
|
|
config.source;
|
|
};
|
|
};
|
|
|
|
fileType = lib.types.submoduleWith {
|
|
shorthandOnlyDefinesConfig = true;
|
|
modules = [ fileTypeModule ];
|
|
specialArgs.topConfig = config;
|
|
};
|
|
|
|
# TODO: Added 2024-07-07, remove after 24.11
|
|
# Before we had a fileType, we used types.str.
|
|
coercedFileType = helpers.transitionType lib.types.str (text: { inherit text; }) fileType;
|
|
in
|
|
{
|
|
options = {
|
|
extraFiles = lib.mkOption {
|
|
type = lib.types.attrsOf coercedFileType;
|
|
description = "Extra files to add to the runtime path";
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
"ftplugin/nix.lua".text = '''
|
|
vim.opt.tabstop = 2
|
|
vim.opt.shiftwidth = 2
|
|
vim.opt.expandtab = true
|
|
''';
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
}
|