mirror of
https://github.com/nix-community/nixvim.git
synced 2025-06-21 00:25:42 +02:00
191b0a9502
In the two places where our "helpers" lib is exclusively internal (flake module args and building the docs), we no longer supply `pkgs`. In the other 4 locations, we now note why we still do in a comment.
50 lines
1.2 KiB
Nix
50 lines
1.2 KiB
Nix
default_pkgs: self:
|
|
{
|
|
pkgs ? default_pkgs,
|
|
lib ? pkgs.lib,
|
|
extraSpecialArgs ? { },
|
|
_nixvimTests ? false,
|
|
module,
|
|
}:
|
|
let
|
|
# NOTE: user-facing so we must include the legacy `pkgs` argument
|
|
helpers = import ../lib { inherit pkgs lib _nixvimTests; };
|
|
|
|
inherit (helpers.modules) evalNixvim;
|
|
|
|
mkNvim =
|
|
mod:
|
|
let
|
|
evaledModule = evalNixvim {
|
|
modules = [
|
|
mod
|
|
./modules/standalone.nix
|
|
];
|
|
extraSpecialArgs = {
|
|
defaultPkgs = pkgs;
|
|
} // extraSpecialArgs;
|
|
};
|
|
inherit (evaledModule.config) enableMan finalPackage printInitPackage;
|
|
in
|
|
(pkgs.symlinkJoin {
|
|
name = "nixvim";
|
|
paths = [
|
|
finalPackage
|
|
printInitPackage
|
|
] ++ pkgs.lib.optional enableMan self.packages.${pkgs.stdenv.hostPlatform.system}.man-docs;
|
|
meta.mainProgram = "nvim";
|
|
})
|
|
// rec {
|
|
inherit (evaledModule) config options;
|
|
extend =
|
|
extension:
|
|
mkNvim {
|
|
imports = [
|
|
mod
|
|
extension
|
|
];
|
|
};
|
|
nixvimExtend = lib.warn "<nixvim>.nixvimExtend has been renamed to <nixvim>.extend" extend;
|
|
};
|
|
in
|
|
mkNvim module
|