mirror of
https://github.com/nix-community/nixvim.git
synced 2025-06-20 16:15:43 +02:00
4e5bd1d79b
Splits everything that depends on a `pkgs` instance into an optional attrs, allowing `helpers.nix` to be bootstrapped without `pkgs`. This required some refactoring: - `modules.specialArgs` is only available when `pkgs` is used - `modules.specialArgsWith` now requires `defaultPkgs` be provided - `builders.*` now have `*With` variants that take `pkgs` as an argument and a `withPkgs` function that returns the old interface - Had to define the fixed part of `builders` outside the attrs for now, to avoid infinite recursion. - The old `builders` are now deprecated, and print a warning when evaluated - `withOptoinalFns` was introduced to merge the optional attrs into the final lib.
63 lines
1.3 KiB
Nix
63 lines
1.3 KiB
Nix
self:
|
|
{
|
|
pkgs,
|
|
config,
|
|
lib,
|
|
...
|
|
}@args:
|
|
let
|
|
inherit (lib)
|
|
mkEnableOption
|
|
mkOption
|
|
mkOptionType
|
|
mkMerge
|
|
mkIf
|
|
types
|
|
;
|
|
cfg = config.programs.nixvim;
|
|
in
|
|
{
|
|
options = {
|
|
programs.nixvim = mkOption {
|
|
default = { };
|
|
type = types.submoduleWith {
|
|
shorthandOnlyDefinesConfig = true;
|
|
specialArgs = config.lib.nixvim.modules.specialArgsWith {
|
|
defaultPkgs = pkgs;
|
|
hmConfig = config;
|
|
};
|
|
modules = [
|
|
./modules/hm.nix
|
|
../modules/top-level
|
|
];
|
|
};
|
|
};
|
|
};
|
|
|
|
imports = [
|
|
(import ./_shared.nix {
|
|
filesOpt = [
|
|
"xdg"
|
|
"configFile"
|
|
];
|
|
})
|
|
];
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
{
|
|
home.packages = [
|
|
cfg.finalPackage
|
|
cfg.printInitPackage
|
|
] ++ (lib.optional cfg.enableMan self.packages.${pkgs.stdenv.hostPlatform.system}.man-docs);
|
|
}
|
|
{
|
|
inherit (cfg) warnings assertions;
|
|
home.sessionVariables = mkIf cfg.defaultEditor { EDITOR = "nvim"; };
|
|
}
|
|
{
|
|
programs.bash.shellAliases = mkIf cfg.vimdiffAlias { vimdiff = "nvim -d"; };
|
|
programs.fish.shellAliases = mkIf cfg.vimdiffAlias { vimdiff = "nvim -d"; };
|
|
programs.zsh.shellAliases = mkIf cfg.vimdiffAlias { vimdiff = "nvim -d"; };
|
|
}
|
|
]);
|
|
}
|