mirror of
https://github.com/nix-community/nixvim.git
synced 2025-06-21 16:39:00 +02:00
4ddd3969e5
This represents a major rearchitecture for nixvim, so I'm leaving this up to track the progress for now, and to serve as a reference for any breaking changes during transition. The main change is, of course, being able to use nixvim standalone. To do this, you should use the new build function, which takes in two arguments: the system architecture (e.g. x86_64-linux) and the configuration. For the new configuration, do not use the programs.nixvim. prefix. For module development, the main change is that you should no longer prefix your modules with programs.nixvim..
46 lines
1.5 KiB
Nix
46 lines
1.5 KiB
Nix
{ pkgs, config, lib, ... }:
|
|
{
|
|
mkServer =
|
|
{ name
|
|
, sourceType
|
|
, description ? "Enable ${name} source, for null-ls."
|
|
, packages ? [ ]
|
|
, ...
|
|
}:
|
|
# returns a module
|
|
{ pkgs, config, lib, ... }@args:
|
|
with lib;
|
|
let
|
|
helpers = import ../helpers.nix args;
|
|
cfg = config.plugins.null-ls.sources.${sourceType}.${name};
|
|
in
|
|
{
|
|
options.plugins.null-ls.sources.${sourceType}.${name} = {
|
|
enable = mkEnableOption description;
|
|
|
|
# TODO: withArgs can exist outside of the module in a generalized manner
|
|
withArgs = mkOption {
|
|
default = null;
|
|
type = with types; nullOr str;
|
|
description = ''Raw Lua code to be called with the with function'';
|
|
# Not sure that it makes sense to have the same example for all servers
|
|
# example = ''
|
|
# '\'{ extra_args = { "--no-semi", "--single-quote", "--jsx-single-quote" } }'\'
|
|
# '';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
extraPackages = packages;
|
|
|
|
# Add source to list of sources
|
|
plugins.null-ls.sourcesItems =
|
|
let
|
|
sourceItem = "${sourceType}.${name}";
|
|
withArgs = if (isNull cfg.withArgs) then sourceItem else "${sourceItem}.with ${cfg.withArgs}";
|
|
finalString = ''require("null-ls").builtins.${withArgs}'';
|
|
in
|
|
[ (helpers.mkRaw finalString) ];
|
|
};
|
|
};
|
|
}
|