packer: init plugin

plugins/default.nix

@@ -5,6 +5,8 @@
     ./colorschemes/one.nix
     ./colorschemes/base16.nix
 
+    ./pluginmanagers/packer.nix
+
     ./statuslines/lightline.nix
     ./statuslines/airline.nix
 

plugins/helpers.nix

@@ -9,10 +9,15 @@ rec {
   # lua equivalents!
   toLuaObject = args:
     if builtins.isAttrs args then
-      "{" + (concatStringsSep ","
-        (mapAttrsToList
-          (n: v: "[${toLuaObject n}] = " + (toLuaObject v))
-        (filterAttrs (n: v: !isNull v || v == {}) args))) + "}"
+      if hasAttr "__raw" args then
+        args.__raw
+      else
+        "{" + (concatStringsSep ","
+          (mapAttrsToList
+          (n: v: if head (stringToCharacters n) == "@" then
+              toLuaObject v
+            else "[${toLuaObject n}] = " + (toLuaObject v))
+          (filterAttrs (n: v: !isNull v || v == {}) args))) + "}"
     else if builtins.isList args then
       "{" + concatMapStringsSep "," toLuaObject args + "}"
     else if builtins.isString args then
@@ -97,4 +102,6 @@ rec {
 
     inherit value global;
   };
+
+  mkRaw = r: { __raw = r; };
 }

plugins/languages/treesitter.nix

@@ -17,8 +17,7 @@ in
 
       disabledLanguages = mkOption {
         type = types.listOf types.str;
-        # Nix is out of date right now! Try not to use it :D
-        default = [ "nix" ];
+        default = [];
         description = "A list of languages to disable";
       };
 
@@ -76,11 +75,17 @@ in
     };
   in mkIf cfg.enable {
     programs.nixvim = {
-      extraPlugins = [ pkgs.vimPlugins.nvim-treesitter ];
-
-      extraConfigLua = ''
-        require('nvim-treesitter.configs').setup(${helpers.toLuaObject tsOptions})
-      '';
+      plugins.packer = {
+        enable = true;
+        plugins = [{
+          name = "nvim-treesitter/nvim-treesitter";
+          run = ":TSUpdate";
+          config = helpers.mkRaw ''function()
+            require('nvim-treesitter.configs').setup(${helpers.toLuaObject tsOptions})
+          end'';
+        }];
+      };
+      extraPackages = [ pkgs.tree-sitter ];
 
       options = mkIf cfg.folding {
         foldmethod = "expr";

plugins/pluginmanagers/packer.nix

@@ -0,0 +1,73 @@
+{ pkgs, config, lib, ... }:
+with lib;
+let
+  cfg = config.programs.nixvim.plugins.packer;
+  helpers = import ../helpers.nix { lib = lib; };
+in {
+  options = {
+    programs.nixvim.plugins.packer = {
+      enable = mkEnableOption "Enable packer.nvim";
+
+      plugins = mkOption {
+        type = types.listOf (types.oneOf [types.str (with types; let 
+          mkOpt = type: desc: mkOption {
+            type = nullOr type;
+            default = null;
+            description = desc;
+          };
+          function = attrsOf str;
+        in types.submodule {
+          options = {
+            name = mkOption {
+              type = str;
+              description = "Name of the plugin to install";
+            };
+
+            disable = mkOpt bool "Mark plugin as inactive";
+            as = mkOpt bool "Specifies an alias under which to install the plugin";
+            installer = mkOpt function "A custom installer";
+            updater = mkOpt function "A custom updater";
+            after = mkOpt (oneOf [str (listOf any)]) "Plugins to load after this plugin";
+            rtp = mkOpt str "Specifies a subdirectory of the plugin to add to runtimepath";
+            opt = mkOpt str "Marks a plugin as optional";
+            branch = mkOpt str "Git branch to use";
+            tag = mkOpt str "Git tag to use";
+            commit = mkOpt str "Git commit to use";
+            lock = mkOpt bool "Skip this plugin in updates";
+            run = mkOpt (oneOf [str function]) "Post-install hook";
+            requires = mkOpt (oneOf [str (listOf any)]) "Plugin dependencies";
+            rocks = mkOpt (oneOf [str (listOf any)]) "Luarocks dependencies";
+            config = mkOpt (oneOf [str function]) "Code to run after this plugin is loaded";
+            setup = mkOpt (oneOf [str function]) "Code to be run before this plugin is loaded";
+            cmd = mkOpt (oneOf [str (listOf str)]) "Commands which load this plugin";
+            ft = mkOpt (oneOf [str (listOf str)]) "Filetypes which load this plugin";
+            keys = mkOpt (oneOf [str (listOf str)]) "Keymaps which load this plugin";
+            event = mkOpt (oneOf [str (listOf str)]) "Autocommand events which load this plugin";
+            fn = mkOpt (oneOf [str (listOf str)]) "Functions which load this plugin";
+            cond = mkOpt (oneOf [str function (listOf (oneOf [str function]))]) "Conditional test to load this plugin";
+            module = mkOpt (oneOf [str (listOf str)]) "Patterns of module names which load this plugin";
+          };
+        })]);
+        default = [];
+        description = "List of plugins";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    programs.nixvim = {
+      extraPlugins = [ pkgs.vimPlugins.packer-nvim ];
+
+      extraConfigLua = let
+        plugins = map (plugin: if isAttrs plugin then
+          mapAttrs' (k: v: { name = if k == "name" then "@" else k; value = v; }) plugin
+        else plugin) cfg.plugins;
+        packedPlugins = if length plugins == 1 then head plugins else plugins;
+      in mkIf (cfg.plugins != []) ''
+        require('packer').startup(function()
+          use ${helpers.toLuaObject packedPlugins}
+        end)
+      '';
+    };
+  };
+}