lib/utils: add literalLua for use in option docs

Creates a `literalExpression` equivalent to using `lib.nixvim.mkRaw`.

lib/default.nix

@@ -92,6 +92,7 @@ lib.fix (
       hasContent
       ifNonNull'
       listToUnkeyedAttrs
+      literalLua
       mkIfNonNull
       mkIfNonNull'
       mkRaw

lib/utils.nix

@@ -124,6 +124,37 @@ rec {
     else
       throw "mkRaw: invalid input: ${lib.generators.toPretty { multiline = false; } r}";
 
+  /**
+    Convert the given string into a literalExpression mkRaw.
+
+    For use in option documentation, such as examples and defaults.
+
+    # Example
+
+    ```nix
+    literalLua "print('hi')"
+    => literalExpression ''lib.nixvim.mkRaw "print('hi')"''
+    => {
+      _type = "literalExpression";
+      text = ''lib.nixvim.mkRaw "print('hi')"'';
+    }
+    ```
+
+    # Type
+    ```
+    literalLua :: String -> AttrSet
+    ```
+  */
+  literalLua =
+    r:
+    let
+      # Pass the value through mkRaw for validation
+      raw = mkRaw r;
+      # TODO: consider switching to lib.generators.mkLuaInline ?
+      exp = "lib.nixvim.mkRaw " + builtins.toJSON raw.__raw;
+    in
+    lib.literalExpression exp;
+
   wrapDo = string: ''
     do
       ${string}

tests/lib-tests.nix

@@ -318,6 +318,19 @@ let
       };
     };
 
+    testLiteralLua = {
+      expr = builtins.mapAttrs (_: helpers.literalLua) {
+        print = "print('hi')";
+        nil = "nil";
+        table = "{}";
+      };
+      expected = builtins.mapAttrs (_: lib.literalExpression) {
+        print = ''lib.nixvim.mkRaw "print('hi')"'';
+        nil = ''lib.nixvim.mkRaw "nil"'';
+        table = ''lib.nixvim.mkRaw "{}"'';
+      };
+    };
+
     testUpperFirstChar = {
       expr = map helpers.upperFirstChar [
         "foo"