mirror/nix-community.nixvim
1
0
Fork 0
mirror of https://github.com/nix-community/nixvim.git synced 2025-06-21 08:35:43 +02:00
Code Issues Projects Releases Packages Wiki Activity Actions 1

luasnip: init plugin (#56)

Browse source 
* luasnip: init plugin

Also added support for paths in `toLuaObject`

* luasnip: more flexible types

* luasnip: changed options to be more flexible

* luasnip: added example

* luasnip: added package option
This commit is contained in:
Alexander Nortung 2022-11-08 20:59:26 +01:00 • committed by GitHub
parent 1a89cd2107
commit cba9cca52b
No known key found for this signature in database
GPG key ID: 4AEE18F83AFDEB23
3 changed files with 102 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

98
plugins/snippets/luasnip/default.nix Normal file
View file

@ -0,0 +1,98 @@
{ pkgs, config, lib, ... }:
with lib;
let
cfg = config.plugins.luasnip;
helpers = import ../../helpers.nix { lib = lib; };
in
{
options.plugins.luasnip = {
enable = mkEnableOption "Enable luasnip";
package = mkOption {
default = pkgs.vimPlugins.luasnip;
type = types.package;
};
fromVscode = mkOption {
default = [ ];
example = ''
[
{}
{
paths = ./path/to/snippets;
}
]
# generates:
#
# require("luasnip.loaders.from_vscode").lazy_load({})
# require("luasnip.loaders.from_vscode").lazy_load({['paths'] = {'/nix/store/.../path/to/snippets'}})
#
'';
type = types.listOf (types.submodule {
options = {
lazyLoad = mkOption {
type = types.bool;
default = true;
description = ''
Whether or not to lazy load the snippets
'';
};
# TODO: add option to also include the default runtimepath
paths = mkOption {
default = null;
type = with types; nullOr (oneOf
[
str
path
helpers.rawType
(listOf (oneOf
[
str
path
helpers.rawType
]))
]);
};
exclude = mkOption {
type = types.nullOr (types.listOf types.str);
default = null;
description = ''
List of languages to exclude, by default is empty.
'';
};
include = mkOption {
type = types.nullOr (types.listOf types.str);
default = null;
description = ''
List of languages to include, by default is not set.
'';
};
};
});
};
# TODO: add support for snipmate
# TODO: add support for lua
};
config =
let
fromVscodeLoaders = lists.map
(loader:
let
options = attrsets.getAttrs [ "paths" "exclude" "include" ] loader;
in
''
require("luasnip.loaders.from_vscode").${optionalString loader.lazyLoad "lazy_"}load(${helpers.toLuaObject options})
'')
cfg.fromVscode;
in
mkIf cfg.enable {
extraPlugins = [ cfg.package ];
extraConfigLua = concatStringsSep "\n" fromVscodeLoaders;
};
}