mirror/nix-community.nixvim
1
0
Fork 0
mirror of https://github.com/nix-community/nixvim.git synced 2025-06-21 00:25:42 +02:00
Code Issues Projects Releases Packages Wiki Activity Actions 1

plugins/dap-ui: migrate to mkNeovimPlugin

Browse source
This commit is contained in:
Austin Horstman 2025-01-26 15:11:29 -06:00
parent a70168e0fa
commit 9eae5db29a
No known key found for this signature in database
5 changed files with 253 additions and 172 deletions
Download patch file Download diff file Expand all files Collapse all files

245
plugins/by-name/dap/dap-ui.nix
View file

@ -1,245 +0,0 @@
{
lib,
config,
pkgs,
...
}:
let
inherit (lib) mkOption types;
inherit (lib.nixvim) defaultNullOpts;
cfg = config.plugins.dap.extensions.dap-ui;
mkSizeOption = lib.nixvim.mkNullOrOption (with types; either int (numbers.between 0.0 1.0));
mkKeymapOptions =
name:
lib.mapAttrs (
key: default:
defaultNullOpts.mkNullable (with types; either str (listOf str)) default "Map `${key}` for ${name}"
);
elementOption = types.submodule {
options = {
id = lib.nixvim.mkNullOrOption types.str "Element ID.";
size = mkSizeOption "Size of the element in lines/columns or as proportion of total editor size (0-1).";
};
};
layoutOption = types.submodule {
options = {
elements = mkOption {
default = [ ];
description = "Elements to display in this layout.";
type = with types; listOf (either str elementOption);
};
size = mkOption {
default = 10;
description = "Size of the layout in lines/columns.";
type = types.int;
};
position = mkOption {
default = "left";
description = "Which side of editor to open layout on.";
type = types.enum [
"left"
"right"
"top"
"bottom"
];
};
};
};
in
{
options.plugins.dap.extensions.dap-ui = lib.nixvim.plugins.neovim.extraOptionsOptions // {
enable = lib.mkEnableOption "dap-ui";
package = lib.mkPackageOption pkgs "dap-ui" {
default = [
"vimPlugins"
"nvim-dap-ui"
];
};
controls = {
enabled = defaultNullOpts.mkBool true "Enable controls";
element = defaultNullOpts.mkEnumFirstDefault [
"repl"
"scopes"
"stacks"
"watches"
"breakpoints"
"console"
] "Element to show the controls on.";
icons = {
disconnect = defaultNullOpts.mkStr "" "";
pause = defaultNullOpts.mkStr "" "";
play = defaultNullOpts.mkStr "" "";
run_last = defaultNullOpts.mkStr "" "";
step_into = defaultNullOpts.mkStr "" "";
step_over = defaultNullOpts.mkStr "" "";
step_out = defaultNullOpts.mkStr "" "";
step_back = defaultNullOpts.mkStr "" "";
terminate = defaultNullOpts.mkStr "" "";
};
};
elementMappings = lib.nixvim.mkNullOrOption (types.attrsOf (
types.submodule {
options = mkKeymapOptions "element mapping overrides" {
edit = "e";
expand = [
"<CR>"
"<2-LeftMouse>"
];
open = "o";
remove = "d";
repl = "r";
toggle = "t";
};
}
)) "Per-element overrides of global mappings.";
expandLines = defaultNullOpts.mkBool true "Expand current line to hover window if larger than window size.";
floating = {
maxHeight = mkSizeOption "Maximum height of the floating window.";
maxWidth = mkSizeOption "Maximum width of the floating window.";
border = defaultNullOpts.mkBorder "single" "dap-ui floating window" "";
mappings = lib.nixvim.mkNullOrOption (types.submodule {
options = mkKeymapOptions "dap-ui floating" {
close = [
"<ESC>"
"q"
];
};
}) "Keys to trigger actions in elements.";
};
forceBuffers = defaultNullOpts.mkBool true "Prevents other buffers being loaded into dap-ui windows.";
icons = {
collapsed = defaultNullOpts.mkStr "" "";
current_frame = defaultNullOpts.mkStr "" "";
expanded = defaultNullOpts.mkStr "" "";
};
layouts = defaultNullOpts.mkListOf layoutOption [
{
elements = [
{
id = "scopes";
size = 0.25;
}
{
id = "breakpoints";
size = 0.25;
}
{
id = "stacks";
size = 0.25;
}
{
id = "watches";
size = 0.25;
}
];
position = "left";
size = 40;
}
{
elements = [
{
id = "repl";
size = 0.5;
}
{
id = "console";
size = 0.5;
}
];
position = "bottom";
size = 10;
}
] "List of layouts for dap-ui.";
mappings = lib.nixvim.mkNullOrOption (types.submodule {
options = mkKeymapOptions "dap-ui" {
edit = "e";
expand = [
"<CR>"
"<2-LeftMouse>"
];
open = "o";
remove = "d";
repl = "r";
toggle = "t";
};
}) "Keys to trigger actions in elements.";
render = {
indent = defaultNullOpts.mkInt 1 "Default indentation size.";
maxTypeLength = lib.nixvim.mkNullOrOption types.int "Maximum number of characters to allow a type name to fill before trimming.";
maxValueLines = defaultNullOpts.mkInt 100 "Maximum number of lines to allow a value to fill before trimming.";
};
selectWindow = defaultNullOpts.mkLuaFn null ''
A function which returns a window to be used for opening buffers such as a stack frame location.
'';
};
config =
let
options =
with cfg;
{
inherit
controls
icons
layouts
mappings
;
element_mappings = elementMappings;
floating = with floating; {
inherit border mappings;
max_height = maxHeight;
max_width = maxWidth;
};
force_buffers = forceBuffers;
render = with render; {
inherit indent;
max_type_length = maxTypeLength;
max_value_lines = maxValueLines;
};
select_window = selectWindow;
}
// cfg.extraOptions;
in
lib.mkIf cfg.enable {
extraPlugins = [ cfg.package ];
plugins.dap = {
enable = true;
extensionConfigLua = ''
require("dapui").setup(${lib.nixvim.toLuaObject options});
'';
};
};
}

1
plugins/by-name/dap/default.nix
View file

@ -13,7 +13,6 @@ let
in
lib.nixvim.plugins.mkNeovimPlugin {
imports = [
./dap-ui.nix
./dap-virtual-text.nix
];