plugins/telescope: refactor mkExtension

Allow importing `mkExtension` without needing to supply any
dependencies.

All dependencies can be accessed via module args anyway.

plugins/by-name/telescope/extensions/_helpers.nix

@@ -1,85 +1,4 @@
-{
+lib: rec {
-  lib,
-  config,
-  pkgs,
-  ...
-}:
-let
-  inherit (lib.nixvim) mkSettingsOption toSnakeCase;
-  inherit (lib) mkPackageOption;
-in
-rec {
-  mkExtension =
-    {
-      name,
-      package,
-      extensionName ? name,
-      settingsOptions ? { },
-      settingsExample ? null,
-      extraOptions ? { },
-      imports ? [ ],
-      optionsRenamedToSettings ? [ ],
-      extraConfig ? cfg: { },
-    }:
-    {
-      # TODO remove this once all deprecation warnings will have been removed.
-      imports =
-        let
-          basePluginPath = [
-            "plugins"
-            "telescope"
-            "extensions"
-            name
-          ];
-          settingsPath = basePluginPath ++ [ "settings" ];
-        in
-        imports
-        ++ (map (
-          option:
-          let
-            optionPath = lib.toList option;
-
-            optionPathSnakeCase = map toSnakeCase optionPath;
-          in
-          lib.mkRenamedOptionModule (basePluginPath ++ optionPath) (settingsPath ++ optionPathSnakeCase)
-        ) optionsRenamedToSettings);
-
-      options.plugins.telescope.extensions.${name} = {
-        enable = lib.mkEnableOption "the `${name}` telescope extension";
-
-        package = mkPackageOption pkgs name {
-          default = [
-            "vimPlugins"
-            package
-          ];
-        };
-
-        settings = mkSettingsOption {
-          description = "settings for the `${name}` telescope extension.";
-          options = settingsOptions;
-          example = settingsExample;
-        };
-      } // extraOptions;
-
-      config =
-        let
-          cfg = config.plugins.telescope.extensions.${name};
-        in
-        lib.mkIf cfg.enable (
-          lib.mkMerge [
-            {
-              extraPlugins = [ cfg.package ];
-
-              plugins.telescope = {
-                enabledExtensions = [ extensionName ];
-                settings.extensions.${extensionName} = cfg.settings;
-              };
-            }
-            (extraConfig cfg)
-          ]
-        );
-    };
-
   # FIXME: don't manually put Default in the description
   # TODO: Comply with #603
   mkModeMappingsOption =

plugins/by-name/telescope/extensions/_mk-extension.nix

@@ -0,0 +1,85 @@
+{
+  name,
+  package,
+  extensionName ? name,
+  settingsOptions ? { },
+  settingsExample ? null,
+  extraOptions ? { },
+  imports ? [ ],
+  optionsRenamedToSettings ? [ ],
+  extraConfig ? cfg: { },
+}:
+let
+  getPluginAttr = attrs: attrs.plugins.telescope.extensions.${name};
+
+  renameModule =
+    { lib, ... }:
+    {
+      # TODO remove this once all deprecation warnings will have been removed.
+      imports =
+        let
+          basePluginPath = [
+            "plugins"
+            "telescope"
+            "extensions"
+            name
+          ];
+          settingsPath = basePluginPath ++ [ "settings" ];
+        in
+        builtins.map (
+          option:
+          let
+            optionPath = lib.toList option;
+            optionPathSnakeCase = map lib.nixvim.toSnakeCase optionPath;
+          in
+          lib.mkRenamedOptionModule (basePluginPath ++ optionPath) (settingsPath ++ optionPathSnakeCase)
+        ) optionsRenamedToSettings;
+    };
+
+  module =
+    {
+      lib,
+      config,
+      pkgs,
+      ...
+    }:
+    let
+      cfg = getPluginAttr config;
+    in
+    {
+      options.plugins.telescope.extensions.${name} = {
+        enable = lib.mkEnableOption "the `${name}` telescope extension";
+
+        package = lib.mkPackageOption pkgs name {
+          default = [
+            "vimPlugins"
+            package
+          ];
+        };
+
+        settings = lib.nixvim.mkSettingsOption {
+          description = "settings for the `${name}` telescope extension.";
+          options = settingsOptions;
+          example = settingsExample;
+        };
+      } // extraOptions;
+
+      config = lib.mkIf cfg.enable {
+        extraPlugins = [ cfg.package ];
+
+        plugins.telescope = {
+          enabledExtensions = [ extensionName ];
+          settings.extensions.${extensionName} = cfg.settings;
+        };
+      };
+    };
+
+  extraConfigModule = { config, ... }: extraConfig (getPluginAttr config);
+in
+{
+  imports = imports ++ [
+    module
+    extraConfigModule
+    renameModule
+  ];
+}

plugins/by-name/telescope/extensions/file-browser.nix

@@ -1,15 +1,11 @@
-{
+{ lib, ... }:
-  lib,
-  config,
-  pkgs,
-  ...
-}:
 with lib;
 let
-  telescopeHelpers = import ./_helpers.nix { inherit lib config pkgs; };
+  inherit (import ./_helpers.nix lib) mkMappingsOption;
+  mkExtension = import ./_mk-extension.nix;
   inherit (lib.nixvim) defaultNullOpts mkNullOrStr;
 in
-telescopeHelpers.mkExtension {
+mkExtension {
   name = "file-browser";
   extensionName = "file_browser";
   package = "telescope-file-browser-nvim";
@@ -183,7 +179,7 @@ telescopeHelpers.mkExtension {
       Show the current relative path from cwd as the prompt prefix.
     '';
 
-    mappings = telescopeHelpers.mkMappingsOption {
+    mappings = mkMappingsOption {
       insertDefaults = ''
         {
           "<A-c>" = "require('telescope._extensions.file_browser.actions').create";

plugins/by-name/telescope/extensions/frecency.nix

@@ -1,14 +1,10 @@
-{
+{ lib, ... }:
-  lib,
-  config,
-  pkgs,
-  ...
-}:
 with lib;
 let
   inherit (lib.nixvim) defaultNullOpts mkNullOrOption mkNullOrStr;
+  mkExtension = import ./_mk-extension.nix;
 in
-(import ./_helpers.nix { inherit lib config pkgs; }).mkExtension {
+mkExtension {
   name = "frecency";
   package = "telescope-frecency-nvim";
 

plugins/by-name/telescope/extensions/fzf-native.nix

@@ -1,13 +1,9 @@
-{
+{ lib, ... }:
-  lib,
-  config,
-  pkgs,
-  ...
-}:
 let
   inherit (lib.nixvim) defaultNullOpts;
+  mkExtension = import ./_mk-extension.nix;
 in
-(import ./_helpers.nix { inherit lib config pkgs; }).mkExtension {
+mkExtension {
   name = "fzf-native";
   extensionName = "fzf";
   package = "telescope-fzf-native-nvim";

plugins/by-name/telescope/extensions/fzy-native.nix

@@ -1,13 +1,9 @@
-{
+{ lib, ... }:
-  lib,
-  config,
-  pkgs,
-  ...
-}:
 let
   inherit (lib.nixvim) defaultNullOpts;
+  mkExtension = import ./_mk-extension.nix;
 in
-(import ./_helpers.nix { inherit lib config pkgs; }).mkExtension {
+mkExtension {
   name = "fzy-native";
   extensionName = "fzy_native";
   package = "telescope-fzy-native-nvim";

plugins/by-name/telescope/extensions/live-greps-args.nix

@@ -1,15 +1,14 @@
 {
   lib,
-  config,
   pkgs,
   ...
 }:
 let
   inherit (lib.nixvim) defaultNullOpts;
   inherit (lib) types;
-  telescopeHelpers = import ./_helpers.nix { inherit lib config pkgs; };
+  mkExtension = import ./_mk-extension.nix;
 in
-telescopeHelpers.mkExtension {
+mkExtension {
   name = "live-grep-args";
   extensionName = "live_grep_args";
   package = "telescope-live-grep-args-nvim";

plugins/by-name/telescope/extensions/manix.nix

@@ -1,15 +1,14 @@
 {
   lib,
-  config,
   pkgs,
   ...
 }:
 let
   inherit (lib.nixvim) defaultNullOpts;
 
-  telescopeHelpers = import ./_helpers.nix { inherit lib config pkgs; };
+  mkExtension = import ./_mk-extension.nix;
 in
-telescopeHelpers.mkExtension {
+mkExtension {
   name = "manix";
   package = "telescope-manix";
 

plugins/by-name/telescope/extensions/media-files.nix

@@ -1,14 +1,14 @@
 {
   lib,
-  config,
   pkgs,
   ...
 }:
 with lib;
 let
   inherit (lib.nixvim) defaultNullOpts;
+  mkExtension = import ./_mk-extension.nix;
 in
-(import ./_helpers.nix { inherit lib config pkgs; }).mkExtension {
+mkExtension {
   name = "media-files";
   extensionName = "media_files";
   package = "telescope-media-files-nvim";

plugins/by-name/telescope/extensions/ui-select.nix

@@ -1,10 +1,7 @@
-{
+let
-  lib,
+  mkExtension = import ./_mk-extension.nix;
-  config,
+in
-  pkgs,
+mkExtension {
-  ...
-}:
-(import ./_helpers.nix { inherit lib config pkgs; }).mkExtension {
   name = "ui-select";
   package = "telescope-ui-select-nvim";
 

plugins/by-name/telescope/extensions/undo.nix

@@ -1,15 +1,11 @@
-{
+{ lib, ... }:
-  lib,
-  config,
-  pkgs,
-  ...
-}:
 with lib;
 let
   inherit (lib.nixvim) defaultNullOpts mkNullOrOption;
-  telescopeHelpers = import ./_helpers.nix { inherit lib config pkgs; };
+  inherit (import ./_helpers.nix lib) mkMappingsOption;
+  mkExtension = import ./_mk-extension.nix;
 in
-telescopeHelpers.mkExtension {
+mkExtension {
   name = "undo";
   package = "telescope-undo-nvim";
 
@@ -84,7 +80,7 @@ telescopeHelpers.mkExtension {
       Can be set to a [Lua date format string](https://www.lua.org/pil/22.1.html).
     '';
 
-    mappings = telescopeHelpers.mkMappingsOption {
+    mappings = mkMappingsOption {
       insertDefaults = ''
         {
           "<cr>" = "require('telescope-undo.actions').yank_additions";