flake: add nixvimConfigurations flake-parts module

flake/default.nix

@@ -4,6 +4,7 @@
     ./flake-modules
     ./lib.nix
     ./legacy-packages.nix
+    ./nixvim-configurations.nix
     ./overlays.nix
     ./packages.nix
     ./templates.nix

flake/flake-modules/default.nix

@@ -1,7 +1,9 @@
 { inputs, ... }:
 let
   # Modules for the flakeModules output and the default module
-  defaultModules = { };
+  defaultModules = {
+    nixvimConfigurations = ./nixvimConfigurations.nix;
+  };
 
   # Modules for the flakeModules output, but not the default module
   extraModules = {

flake/flake-modules/nixvimConfigurations.nix

@@ -0,0 +1,21 @@
+{ lib, flake-parts-lib, ... }:
+let
+  configurationType = lib.mkOptionType {
+    name = "configuration";
+    description = "configuration";
+    descriptionClass = "noun";
+    merge = lib.options.mergeOneOption;
+    check = x: x._type or null == "configuration";
+  };
+in
+flake-parts-lib.mkTransposedPerSystemModule {
+  name = "nixvimConfigurations";
+  option = lib.mkOption {
+    type = lib.types.lazyAttrsOf configurationType;
+    default = { };
+    description = ''
+      An attribute set of Nixvim configurations.
+    '';
+  };
+  file = ./nixvimConfigurations.nix;
+}

flake/legacy-packages.nix

@@ -1,19 +1,15 @@
-{ helpers, ... }:
 {
   perSystem =
     {
+      config,
       makeNixvimWithModule,
-      system,
       ...
     }:
     {
       legacyPackages = rec {
         inherit makeNixvimWithModule;
         makeNixvim = module: makeNixvimWithModule { inherit module; };
-
+        nixvimConfiguration = config.nixvimConfigurations.default;
-        nixvimConfiguration = helpers.modules.evalNixvim {
-          inherit system;
-        };
       };
     };
 }

flake/nixvim-configurations.nix

@@ -0,0 +1,10 @@
+{ helpers, ... }:
+{
+  perSystem =
+    { system, ... }:
+    {
+      nixvimConfigurations.default = helpers.modules.evalNixvim {
+        inherit system;
+      };
+    };
+}